evaluationDependsOn(':common')
evaluationDependsOn(':openbis_api')
evaluationDependsOn(':openbis-common')
evaluationDependsOn(':authentication')
evaluationDependsOn(':dbmigration')
evaluationDependsOn(':openbis')

apply from: '../gradle/javaproject.gradle'

configurations.create('testRuntimeFirst')
configurations.create('testRuntimeSecond')

dependencies {
	compile project(':common'),
			project(':openbis-common'),
			project(':openbis'),
			// authentication and dbmigration are required as they contain later versions of 
			// some classes than cisd-cifex.jar. They need to be in classpath before cisd-cifex.jar
			project(':authentication'),
			project(':dbmigration'),
			'apache:ftpserver-core:1.0.6',
			'apache:sshd-core:0.8.0',
			'jfree:jfreechart:1.0.13',
			'cisd:cisd-cifex:r33473',
			'shriop:javacsv:2.0',
			'cisd:cisd-image-readers:r28194',
			'hjg:pngj:0.62',
			'apache:commons-fileupload:1.2.1',
			'lyncode:xoai-data-provider:4.1.0'

	runtime 'sun:jai:1.1.3-CISD'
				
	testCompile project(path: ':common', configuration: 'tests'),
				project(path: ':openbis-common', configuration: 'tests'),
				project(path: ':openbis', configuration: 'tests')						

	testRuntimeFirst 'javax:servlet-api:3.1.0'
	testRuntimeSecond 'google:gwt-user:2.4'
}

configurations {
	testRuntime.exclude group: 'google', module: 'gwt-servlet'
}

sourceSets.test.runtimeClasspath = configurations.testRuntimeFirst + configurations.testRuntimeSecond + sourceSets.test.runtimeClasspath

sourceSets { 
	test {
		resources {
			srcDirs = ['source/java']
		}
	}
}

jar {
    from('targets/dist') {
        include 'BUILD*INFO'
    }
    from('source/java') {
        include '*.xml'
    }
    from('source') {
        include 'sql/**/*.sql'
        into 'datastore_server'
    }
}