evaluationDependsOn(':common')
evaluationDependsOn(':openbis_api')
evaluationDependsOn(':openbis-common')
evaluationDependsOn(':authentication')
evaluationDependsOn(':dbmigration')
evaluationDependsOn(':openbis')
evaluationDependsOn(':datastore_server')

apply from: '../gradle/javaproject.gradle'

archivesBaseName = 'datastore_server_plugin-dsu'

configurations.create('trackingClient')

dependencies {
	compile project(':common'),
            project(':openbis-common'),
            project(':openbis_api'),
            project(':openbis'),
            project(':datastore_server')

    testCompile project(path: ':datastore_server', configuration: 'tests')
    
    trackingClient 'cisd:cisd-base:r31435',
                   'javax:activation:1.1.1',
                   'javax:mail:1.4.3',
                   'apache:log4j:1.2.15',
                   'springframework:spring:2.5.6.SEC03',
                   'marathon:marathon-spring-util:1.2.3',
                   'apache:httpclient:4.2.1'
}

task trackingJar(type: Jar) {
    archiveName "openbis-tracking-qgf-client.jar"

    from zipTree(project(':common').jar.archivePath).plus(
         zipTree(project(':openbis-common').jar.archivePath).plus( 
         zipTree(project(':openbis_api').jar.archivePath).plus( 
         zipTree(project(':datastore_server').jar.archivePath).plus( 
         zipTree(project(':openbis').jar.archivePath))))).matching {
            include '**/*.class'
    }
    
    from (sourceSets.main.output.classesDir) {
        include '**/*'
    }    

    manifest {
        attributes 'Main-Class': 'ch.ethz.bsse.cisd.dsu.tracking.main.TrackingClient',
                   "Class-Path": configurations.trackingClient.files.collect { it.getName() }.join(' ')
    }
}

task trackingZip(type: Zip, dependsOn: [trackingJar]) {
    baseName = "openbis-tracking-qgf-client"

    from (trackingJar.archivePath) {
        into "tracking/lib"
    }

    from (configurations.trackingClient.files) {
        into "tracking/lib"
    }
    
    from ('tracking/dist/etc') {
        into "tracking/etc"
    }

    from ('tracking/dist/tracking.sh') {
        into "tracking/"
    }
}

task zip(type: Zip) {
	includeEmptyDirs false
    from (jar.archivePath) {
	    into 'datastore_server/lib/'
	    rename 'datastore_server_plugin-dsu(.*)\\.jar', 'datastore_server_plugin-dsu.jar'
	}
    
    from (fileTree(dir: 'source/core-plugins', includes:['illumina-ngs/**'], excludes:['**/as/**', '**/package-to-dist'])) {
		into 'core-plugins'    
	}
}

zip.dependsOn jar
build.dependsOn zip
build.dependsOn trackingZip